Datei:Einwohnerentwicklung von Trier - ab 1871.svg

Seiteninhalte werden in anderen Sprachen nicht unterstützt.
Us der alemannische Wikipedia, der freie Dialäkt-Enzyklopedy

Originaldatei(SVG-Datei, Basisgrößi: 800 × 400 Pixel, Dateigrößi: 61 KB)

Die Datei un d Informatione derzue were us em zäntrale Mediearchiv Wikimedia Commons (Allmänd) iibunde. Zur Bschriibigssite uff de Allmänd Zur Bschriibigssite uff de Allmänd

Bschryybig

Bschryybig
Deutsch: Einwohnerentwicklung von Trier
Quälle Eigeni Arbet
Urheber Summer ... hier! (Diskussion) 17:17, 11 January 2018 (UTC)

Lizänzierig

Ich haa s Urheberrächt an däm Wärch un vereffetlig s dodermit unter däre Lizänz:
Creative Commons CC-Zero Die Datei isch verfiegbar gmacht wore unter em Creative Commons CC0 1.0 Verzicht uf s Copyright.
D Person, wu s Wärch mit däm Dokumänt verbunde het, het des Wärch wältwyt unter d Gmeinfrejheit gstellt un dodermit uf alli Urheber- un Urheberpersenligkeitsrächt, derzue uf alli verwandte Schutzrächt an däm Wärch verzichtet, im Ramme vu dr gsetzlige Bstimmige. S Wärch cha – sälbscht fir kommerziälli Zwäck – kopiert, modifiziert un wyterverteilt wäre, ohni ass mer doderfir um Erlaubnis mueß froge.

Gnuplot script to generate this plot

 
Dieser W3C-unbestimmte Plot wurde mit Gnuplot erstellt.
 
W3C-validity not checked.
#!/usr/bin/gnuplot
# gnuplot 


# Variablen - die wichtigsten Paramter dieser Grafik:
# (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern)
my_data               = 'Einwohnerentwicklung_von_Trier.dat'
my_xrange_min         = '01.01.1871'
my_xrange_max         = '31.12.2017'
my_xtics_years        = '25'
my_mxtics             = '5'
my_yrange_min         = '0'
my_yrange_max         = '*'    # Nur hier ist '*' erlaubt und sinnvoll
my_ytics              = '25000'
my_ymtics             = '5'


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"          # Zeitangaben in TT.MM.YYYY
set datafile separator ";"      # Spaltenseparator 
set datafile commentschars "#"  # Kommentarzeichen 
  stats my_data  u (strptime("%d.%m.%Y",strcol(1))) nooutput 
  my_diff = (STATS_max - STATS_min) / (60*60*24*365.25)
  print '     -----Stats-(Timestamp)----'
  print '     Start:          ', STATS_min
  print '     Ende:           ', STATS_max
  print '     Diff in Jahren: ', my_diff
  print '     --------------------------'
  # Anmerk.: die ausgegebenen Timestamps können in einer Shell bequem mit 
  # 'date -d @[Wert]' in humanleseriches Format gewandelt werden

# Allgemeines zur Ausgabe
set key vertical maxrows 6 # Max Anzahl Zeilen
set key left top           # Legende links oben
set key opaque             # ohne Transparenz 
set key samplen 2          # Breite der Linenbeispiele 
unset key                  # direkt vorher gesetzte Werte aufgehoben; ggf auskommentieren! 
set style data lines       # wird bei 'plot' überschrieben 
set style fill transparent solid 0.4 # wird ebenfalls bei 'plot' überschrieben
set border 3               # Rahmen unten (Bit 1) und links (+ Bit 2) 
set grid                   # Gitterlinien verwenden
# Gitterlinienen per Hand setzen falls gewünscht 
set style line 1 linetype rgb '#696969' linewidth 0.5 dashtype 0 # Def. Major-grid
set style line 2 linetype rgb '#C9C9C9' linewidth 0.5 dashtype 3 # def. Minor-grid
set grid  xtics mxtics     # eventuell noxtics und nomxtics
set grid  ytics mytics     # eventuell noytics und nomytics
set grid  back             # Gitter im Hintergrund
set grid  linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor 
#show grid                  # Kontrollausgabe auf der Konsole


# Farben - nummerische Equavalente zu Namen nach: 
# https://www2.uni-hamburg.de/Wiss/FB/15/Sustainability/schneider/gnuplot/colors.htm
# Die beiden Ziffen am Ende der Variablen geben  opacity/transparenz an
#
my_darkred_00       = '#008B0000';     my_darkred_20       = '#208B0000';
my_darkred_40       = '#408B0000';     my_darkred_60       = '#608B0000';
my_darkred_80       = '#808B0000';     my_darkred_a0       = '#a08B0000';
my_darkred_c0       = '#c08B0000';     my_darkred_e0       = '#e08B0000';
#
my_darkgreen_00     = '#00006400';     my_darkgreen_20     = '#20006400';
my_darkgreen_40     = '#40006400';     my_darkgreen_60     = '#60006400';
my_darkgreen_80     = '#80006400';     my_darkgreen_a0     = '#a0006400';
my_darkgreen_c0     = '#c0006400';     my_darkgreen_e0     = '#e0006400';
#
my_darkblue_00      = '#0000008B';     my_darkblue_20      = '#2000008B';
my_darkblue_40      = '#4000008B';     my_darkblue_60      = '#6000008B';
my_darkblue_80      = '#8000008B';     my_darkblue_a0      = '#a000008B';
my_darkblue_c0      = '#c000008B';     my_darkblue_e0      = '#e000008B';
#
my_darkmagenta_00   = '#008B008B';     my_darkmagenta_20   = '#208B008B';
my_darkmagenta_40   = '#408B008B';     my_darkmagenta_60   = '#608B008B';
my_darkmagenta_80   = '#808B008B';     my_darkmagenta_a0   = '#a08B008B';
my_darkmagenta_c0   = '#c08B008B';     my_darkmagenta_e0   = '#e08B008B';
# 
my_darkorange_00    = '#00FF8C00';     my_darkorange_20    = '#20FF8C00';
my_darkorange_40    = '#40FF8C00';     my_darkorange_60    = '#60FF8C00';
my_darkorange_80    = '#80FF8C00';     my_darkorange_a0    = '#a0FF8C00';
my_darkorange_c0    = '#c0FF8C00';     my_darkorange_e0    = '#e0FF8C00';
#
my_darkturquoise_00 = '#0000CED1';     my_darkturquoise_20 = '#2000CED1';
my_darkturquoise_40 = '#4000CED1';     my_darkturquoise_60 = '#6000CED1';
my_darkturquoise_80 = '#8000CED1';     my_darkturquoise_a0 = '#a000CED1';
my_darkturquoise_c0 = '#c000CED1';     my_darkturquoise_e0 = '#e000CED1'; 
#
my_black_00         = '#00000000';     my_black_20         = '#20000000';
my_black_40         = '#40000000';     my_black_60         = '#60000000';
my_black_80         = '#80000000';     my_black_a0         = '#a0000000';
my_black_c0         = '#c0000000';     my_black_e0         = '#e0000000';


# Bereiche/Format/etc X-Achse 
set xdata time             # X-Achse als Zeitachse
set xlabel 'Jahr'          # Beschriftung X-Achse
set xlabel offset 0, 0.75  # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
                           # Wertebreich der X-Achse
set xtics '01.01.1000', (60*60*24*365.25) * my_xtics_years
                           # xtics in Sekunden 
                           # der Beginn (Wert vor dem Komma) der X-Einteilung 
                           # kann außerhalb xrange liegen
set xtics offset  0, 0.5   # Beschriftung näher an die X-Achse
set mxtics my_mxtics       # Skalenstriche 
set xtics nomirror         # Nur unten Skalieren
set format x '%3Y'         # Beschr.format JJJJ (bei 3 Stellen o. führend 0)
set xtics  out             # Skal. aussen damit sie nicht von Grafik 
                           # überschr. wird


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label 
# Untere Begrenzung des Bereichs der Y-Achse
set yrange [ my_yrange_min : ]
# Obere  Begrenzung des Bereichs der Y-Achse
# wir Testen ob der Wert der Var.  my_yrange_max ein '*' ist und reagieren 
# entsprechend weil der '*' sich nicht direkt via Var. setzen lässt. 
if ( ( my_yrange_max eq '*' )) set yrange [ : *             ]
if (!( my_yrange_max eq '*' )) set yrange [ : my_yrange_max ]
set ytics my_ytics         # Anzahl der kleinen Teilstriche
set ytics offset 0.5       # Schrift etwas nach rechts
set ytics nomirror         # oben keine Teilstriche
set decimalsign locale "de_DE.utf8" # Stelle Input und Output auf "," um 
                           # set decimalsign ',' würde nur Output umstellen, 
set format y  "%'.0f"      # Ausgabeformat
set mytics my_ymtics       # Unterskalierung 
set ytics  out             # Skal. aussen da sie sonst von Grafik 
                           # überschr. wird


#### Markierungsbalken für die beiden Weltkriege etc.
# Die set-Befehle ggf. auskommentieren
# Attribute für Markierungsbalken
set style rect fillcolor lt -1 fillstyle solid 0.1 noborder
#
# == Dreißigjähriger Krieg
  set obj rect from '23.05.1618', graph 0 to '24.10.1648' , graph 1 back
  set label "Dreißigjähriger Krieg" at '30.06.1633', graph 0.8 rotate by +60 center front
# == Siebenjähriger Krieg
# set obj rect from '29.08.1756', graph 0 to '21.09.1762' , graph 1 back
# set label "Siebenjähriger Krieg"  at '30.06.1759', graph 0.8 rotate by +60 center front
# == Hamburger Franzosenzeit
# set obj rect from '30.06.1806', graph 0 to '30.06.1814' , graph 1
# set label "H. Franzosenzeit" at '01.01.1810', graph 0.3  rotate by +60 center
# == Befreiungskriege
#set obj rect from '26.02.1813', graph 0 to '20.11.1815' , graph 1 back
#set label "Befreiungskriege"      at '30.06.1814', graph 0.8 rotate by +60 center front
# == 1. Weltkrieg
  set obj rect from '28.07.1914', graph 0 to '11.11.1918' , graph 1 front
  set label "1. Weltkrieg"          at '30.06.1916', graph 0.9 rotate by +60 center front
# == 2. Weltkrieg
  set obj rect from '01.09.1939', graph 0 to '04.05.1945' , graph 1 front
  set label "2. Weltkrieg"          at '30.06.1942', graph 0.9 rotate by +60 center front
# == Dädärä
# set obj rect from '07.10.1949', graph 0 to '03.10.1990' , graph 1 back
# set label "DDR"                   at '01.01.1970', graph 0.9 rotate by +60 center front
#
# == Markierung für Großstadtgrenze 
# Mit Ein-/Auskommentieren festlegen ob bei 100.000 eine vertikale Linie gezogen werden soll 
  set arrow from my_xrange_min, '100000' to my_xrange_max, '100000' nohead lc rgb '#B0FF0000' back
# == Markierung für Millionenstadtgrenze 
# Mit Ein-/Auskommentieren festlegen ob bei 100.000 eine vertikale Linie gezogen werden soll 
  set arrow from my_xrange_min, '1000000' to my_xrange_max, '1000000' nohead lc rgb '#B0FF0000' back


# Außenränder (keine Angabe entspricht Automatik)
set bmargin 
set lmargin 
set rmargin 1.5 # rechts entspr. der Wert bei Auto etwa 2.8
set tmargin 


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so beim Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg) 
# Windowsbenutzer, die mit Pipes nicht umgehen könnten, sollten das Kommentar-
# zeichen vor dem  'set output ...' folgenden Befehl entfernen. 
# set output 'Einwohnerentwicklung_von_Trier.svg' 
set term svg size 800,400 font "Arial,16"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer 
# Einbindung [[Datei:Einwohnerentwicklung_von_Trier.svg|mini|400px|Text]] noch Schrift/Details 
# erkennen kann. 


# Abkürzungen hinter dem Plot-Befehl:
#       u : using
#       w : with
#      lc : linecolor
#      lt : linetype 
#      lw : linewidth
#      pt : pointtype  
#      ps : pointsize
#      lp : linespoints
#       p : points
#       t : title
#     not : notitle
# filledc : filledcurves (Bsp.: File:Einwohnerentwicklung von Wanne-Eickel.svg)
#     rgb : RedGreenBlue

# Daten per Here-Document
# (siehe Abschntt 'Inline data and datablocks' in
# http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HD_1 << EndOfData_1
# bei 'plot' mit '$my_HD_1 use 1:2 with ...' einbinden
...
EndOfData_1


# Jede Kurve wird zweimal gezeichnet. Beim ersten mal mit etwas Transparenz
# damit es heller wird. Beim zweiten mal werden die Punkt dunkel
# nachgezeichnet. Dadurch sollte der Betrachter besser erkennen können, wo
# Messpunkte fehlen. 
#
# Erzeugen der Ausgabe 
plot \
  my_data  u 1:2 w lp lc rgb my_darkblue_40  lt 1 lw 1.5 pt 7 ps 0.22   t 'Einw. Entw.',\
  my_data  u 1:2 w  p lc rgb my_darkblue_00  lt 1 lw 1.5 pt 7 ps 0.22 not              ,\
# $my_HD_1 u 1:2 w lp lc rgb my_darkred_40   lt 1 lw 1.5 pt 7 ps 0.22   t 'Einw. Entw.',\
# $my_HD_1 u 1:2 w  p lc rgb my_darkred_00   lt 1 lw 1.5 pt 7 ps 0.22 not              ,\

Daten

Die folgenden Daten bitte in eine Textdatei unter dem Namen "Einwohnerentwicklung_von_Trier.dat" abspeichern und ins gleiche Verzeichnis wie das GnuPlot-Script ablegen.

Update der Daten und Überschreiben der Grafik ausdrücklich erwünscht (bei Problemen beim Erstellen einer neuen Grafik unter de:Benutzer Diskussion:Summer ... hier! oder de:Wikipedia:Grafikwerkstatt nachfragen).

Vor Änderungen der Struktur dieses Abschnitts bitte beachten, das die Daten zur Wartung anderer Grafiken benutzt werden. Dies sind Dateien, die möglicherweise die Daten dieses Abschnitts verwenden.

#
# Quelle:
# https://de.wikipedia.org/wiki/Einwohnerentwicklung_von_Trier
#
30.06.100 ;20000
30.06.300 ;80000
30.06.400 ;50000
# Beginn groessere Datenlücke (fuer gestrichelte Linie)
30.06.400 ;       ; 50000
30.06.1250;       ;12000
# Ende groessere Datenlücke
30.06.1250;12000
30.06.1363;10000
30.06.1542;8500
30.06.1613;6000
30.06.1697;2677
30.06.1702;4200
30.06.1801;8829
01.12.1831;14723
01.12.1840;15717
#
03.12.1855;20172
03.12.1858;20060
01.12.1871;21442
01.12.1875;22100
01.12.1880;24200
01.12.1885;26126
01.12.1890;36166
02.12.1895;40026
01.12.1900;43506
01.12.1905;46709
01.12.1910;49112
01.12.1916;47107
#
05.12.1917;45709
08.10.1919;53248
16.06.1925;57341
16.06.1933;76692
17.05.1939;88150
31.12.1945;57599
29.10.1946;63420
13.09.1950;75526
25.09.1956;84869
06.06.1961;87141
31.12.1965;86808
27.05.1970;103724
###
31.12.1971;103387
31.12.1972;103048
31.12.1973;102228
31.12.1974;101145
31.12.1975;100338
31.12.1976;99107
31.12.1977;97822
31.12.1978;96787
31.12.1979;95736
31.12.1980;95536
31.12.1981;95180
31.12.1982;94683
31.12.1983;95070
#
31.12.1984;94190
31.12.1985;93472
31.12.1986;93076
25.05.1987;94118
31.12.1987;94548
31.12.1988;95692
31.12.1989;96721
31.12.1990;97835
31.12.1991;98752
31.12.1992;98958
31.12.1993;99183
31.12.1994;99602
31.12.1995;99428
#
31.12.1996;99750
31.12.1997;99691
31.12.1998;99650
31.12.1999;99891
31.12.2000;99410
31.12.2001;100024
31.12.2002;100234
31.12.2003;100180
31.12.2004;100163
31.12.2005;99843
31.12.2006;103518
31.12.2007;103888
31.12.2008;104640
#
31.12.2009;104587
31.12.2010;105260
09.05.2011;105671 #https://de.wikipedia.org/w/index.php?title=Einwohnerentwicklung_von_Trier&diff=175112079&oldid=175095314
31.12.2011;106284
31.12.2012;106544
31.12.2013;107233
31.12.2014;108472
31.12.2015;114914 
31.12.2016;110111 #https://de.wikipedia.org/w/index.php?title=Einwohnerentwicklung_von_Trier&type=revision&diff=175095314&oldid=172824448
31.12.2017;110013
EOF

Kurzbeschreibungen

Ergänze eine einzeilige Erklärung, was diese Datei darstellt.

In dieser Datei abgebildete Objekte

Motiv

Lizenz Tüütsch

CC0 Tüütsch

Dateiversione

Klick uf e Zytpunkt zu aazeige, wie s dert usgsäh het.

Version vomVorschaubildMäßBenutzerKommentar
aktuell17:06, 1. Nov. 2018Vorschaubild fir Version vum 17:06, 1. Nov. 2018800 × 400 (61 KB)Summer ... hier!+Wert 2017
13:46, 18. Mär. 2018Vorschaubild fir Version vum 13:46, 18. Mär. 2018800 × 400 (85 KB)Summer ... hier!+Wert Zensus 2011 gegenüber vorletzter Version; +Wert 2016 gegenüber vorletzter Version; GnuPlot Quellcode und CSV-Daten passend zur akt. Grafik
14:27, 17. Mär. 2018Vorschaubild fir Version vum 14:27, 17. Mär. 20181.800 × 800 (16 KB)Antonsusiupdate
19:17, 11. Jan. 2018Vorschaubild fir Version vum 19:17, 11. Jan. 2018800 × 400 (33 KB)Summer ... hier!{{Information |Description = {{de|Einwohnerentwicklung von Trier}} |Source = {{own}} |Author = ~~~~ |Date = }} == {{int:license-header}} == {{self|Cc-zero}} == Gnuplot script to generate this plot == {{gnuplot}}{{ValidSV...

Di folgende Sytene händ en Link zu dem Bildli:

Wältwyti Dateinutzig

Die andere Wikis bruche die Datei:

Metadate